source: trollforge/lenny/wpspell.tcl @ 183

#!/usr/local/bin/tclsh

package require http
package require htmlparse
package require struct
package require fileutil

# Get random url
set q [::http::geturl "http://en.wikipedia.org/wiki/Special:Random"]
array set meta [set [set q](meta)]
set url $meta(Location)
array unset meta
::http::cleanup $q

# Modify page url
regexp {/([^/]+)$} $url m title
set url "http://en.wikipedia.org/w/index.php?title=$title&action=edit"

# Get and parse random page
set q [::http::geturl $url]
::struct::tree ht
::htmlparse::2tree [::http::data $q] ht
::http::cleanup $q

set ta_found 0
set ta_tmp [::fileutil::tempfile]

ht walk root -- nid {

    array set nd [ht getall $nid]

    switch -exact -- $nd(type) {

                textarea {
                
                        set ta_found 1
                }


                PCDATA {
                
                        if {$ta_found} {
                        
                                set fd [open $ta_tmp w]
                                puts $fd [::htmlparse::mapEscapes $nd(data)]
                                close $fd
                                
                                set ta_found 0
                        }
                }
        }
}

ht destroy

set ta_spell [exec aspell -d en -a < $ta_tmp 2> /dev/null]
file delete -force -- $ta_tmp

array set ta_rep ""

foreach l [split $ta_spell "\n"] {

        if {[regexp {^[&] ([^ ]+) ([^:]+): (.+)$} $l m a b c]} {

                array set ta_rep [list $a [split [regsub -all -- {, } $c "|"] "|"]]

        } elseif {[regexp {^[#] ([^ ]+) } $l m a]} {

                array set ta_rep [list $a {}]
        }
}

puts $url
puts ----

foreach {k v} [array get ta_rep] {

        puts [format "%20s | %-56s" $k [string range $v 0 55]]
}

puts ----